openstack/puppet-cinder
Code Issues Proposed changes

Support for Cinder IBM Svf driver

Browse Source 
This patch adds support for Cinder IBM Spectrum virtualize family (Svf)
driver.

Change-Id: I43f954879de6ce70237cb468e7ef1fbc2649edcd
This commit is contained in:
katarimanoj 2022-10-25 23:31:05 +05:30
parent de6271d895
commit fa671e8ed6
3 changed files with 214 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

113
manifests/backend/ibm_svf.pp Normal file
View File

@ -0,0 +1,113 @@
#
# == Define: cinder::backend::ibm_svf
#
# Setup Cinder to use the IBM Spectrum Virtualize Family(Svf) Driver
# Compatible for multiple backends
#
# == Parameters
#
# [*san_ip*]
# (required) IP address of IBM Svf SAN controller.
#
# [*san_login*]
# (required) Username for IBM Svf SAN controller.
#
# [*san_password*]
# (required) Password for IBM Svf SAN controller.
#
# [*storwize_svc_volpool_name*]
# (required) Comma separated list of storage pools for volumes.
#
# [*storwize_svc_allow_tenant_qos*]
# (optional) Allow tenants to specify QoS on create.
# Defaults to $::os_service_default.
#
# [*storwize_svc_connection_protocol*]
# (optional) The Storage protocol, iSCSI or FC.
# This determines the Volume Driver to be
# configured; StorwizeSVCISCSIDriver or StorwizeSVCFCDriver.
# Defaults to 'iSCSI'
#
# [*storwize_svc_iscsi_chap_enabled*]
# (optional) Configure CHAP authentication for iSCSI connections.
# Defaults to $::os_service_default.
#
# [*storwize_svc_retain_aux_volume*]
# (optional) Defines an optional parameter to retain an auxiliary volume
# in a mirror relationship upon deletion of the primary volume or moving
# it to a non-mirror relationship.
# Defaults to $::os_service_default.
#
# [*volume_backend_name*]
# (optional) The storage backend name.
# Defaults to the name of the backend
#
# [*backend_availability_zone*]
# (Optional) Availability zone for this volume backend.
# If not set, the storage_availability_zone option value
# is used as the default for all backends.
# Defaults to $::os_service_default.
#
# [*manage_volume_type*]
# (Optional) Whether or not manage Cinder Volume type.
# If set to true, a Cinder Volume type will be created
# with volume_backend_name=$volume_backend_name key/value.
# Defaults to false.
#
# [*extra_options*]
# (optional) Hash of extra options to pass to the backend stanza
# Defaults to: {}
# Example :
# { 'ibm_svf_backend/param1' => { 'value' => value1 } }#
#
define cinder::backend::ibm_svf (
$san_ip,
$san_login,
$san_password,
$storwize_svc_volpool_name,
$storwize_svc_allow_tenant_qos = $::os_service_default,
$storwize_svc_connection_protocol = 'iSCSI',
$storwize_svc_iscsi_chap_enabled = $::os_service_default,
$storwize_svc_retain_aux_volume = $::os_service_default,
$volume_backend_name = $name,
$backend_availability_zone = $::os_service_default,
$extra_options = {},
$manage_volume_type = false,
) {
include cinder::deps
# NOTE: Svf was earlier called as storwize/svc driver, so the cinder
# configuration parameters were named accordingly.
if $storwize_svc_connection_protocol == 'iSCSI' {
$volume_driver = 'cinder.volume.drivers.ibm.storwize_svc.storwize_svc_iscsi.StorwizeSVCISCSIDriver'
}
elsif $storwize_svc_connection_protocol == 'FC' {
$volume_driver = 'cinder.volume.drivers.ibm.storwize_svc.storwize_svc_fc.StorwizeSVCFCDriver'
}
else {
fail('The cinder::backend::ibm_svf storwize_svc_connection_protocol specified is not valid. It should be iSCSI or FC')
}
cinder_config {
"${name}/volume_backend_name": value => $volume_backend_name;
"${name}/backend_availability_zone": value => $backend_availability_zone;
"${name}/volume_driver": value => $volume_driver;
"${name}/san_ip": value => $san_ip;
"${name}/san_login": value => $san_login;
"${name}/san_password": value => $san_password, secret => true;
"${name}/storwize_svc_volpool_name": value => join(any2array($storwize_svc_volpool_name), ',');
"${name}/storwize_svc_allow_tenant_qos": value => $storwize_svc_allow_tenant_qos;
"${name}/storwize_svc_iscsi_chap_enabled": value => $storwize_svc_iscsi_chap_enabled;
"${name}/storwize_svc_retain_aux_volume": value => $storwize_svc_retain_aux_volume;
}
if $manage_volume_type {
cinder_type { $volume_backend_name:
ensure => present,
properties => ["volume_backend_name=${volume_backend_name}"],
}
}
create_resources('cinder_config', $extra_options)
}

4
releasenotes/notes/Add_support_for_ibm_svf_driver-803e3cbfc82e39d9.yaml Normal file
View File

@ -0,0 +1,4 @@
---
features:
- |
Add support for Cinder IBM Spectrum virtualize family (Svf) driver.

97
spec/defines/cinder_backend_ibm_svf_spec.rb Normal file
View File

@ -0,0 +1,97 @@
require 'spec_helper'
describe 'cinder::backend::ibm_svf' do
let (:config_group_name) { 'ibm_svf' }
let (:title) { config_group_name }
let :params do
{
:san_ip => '127.0.0.2',
:san_login => 'Admin',
:san_password => '12345',
:storwize_svc_volpool_name => 'svfpool',
}
end
shared_examples 'cinder::backend::ibm_svf' do
context 'with default parameters' do
it 'should configure an iSCSI ibm_svf backend' do
is_expected.to contain_cinder__backend__ibm_svf(config_group_name)
is_expected.to contain_cinder_config("#{title}/volume_driver").with_value(
'cinder.volume.drivers.ibm.storwize_svc.storwize_svc_iscsi.StorwizeSVCISCSIDriver'
)
is_expected.to contain_cinder_config("#{title}/san_ip").with_value('127.0.0.2')
is_expected.to contain_cinder_config("#{title}/san_login").with_value('Admin')
is_expected.to contain_cinder_config("#{title}/san_password").with_value('12345')
is_expected.to contain_cinder_config("#{title}/storwize_svc_volpool_name").with_value('svfpool')
is_expected.to contain_cinder_config("#{title}/backend_availability_zone").with_value('<SERVICE DEFAULT>')
end
end
context 'with storwize_svc_connection_protocol set to FC' do
before do
params.merge!(:storwize_svc_connection_protocol => 'FC',)
end
it 'should configure the FC driver' do
is_expected.to contain_cinder_config("#{title}/volume_driver").with_value(
'cinder.volume.drivers.ibm.storwize_svc.storwize_svc_fc.StorwizeSVCFCDriver'
)
end
end
context 'with an invalid storwize_svc_connection_protocol' do
before do
params.merge!(:storwize_svc_connection_protocol => 'BAD',)
end
it 'should raise an error' do
is_expected.to compile.and_raise_error(
/The cinder::backend::ibm_svf storwize_svc_connection_protocol specified is not valid. It should be iSCSI or FC/
)
end
end
context 'with custom backend_availability_zone' do
before do
params.merge!(:backend_availability_zone => 'my_zone')
end
it 'should configure the backend_availability_zone' do
is_expected.to contain_cinder_config("#{title}/backend_availability_zone").with_value('my_zone')
end
end
context 'ibm_svf backend with additional configuration' do
before do
params.merge!( :extra_options => {'ibm_svf/param1' => { 'value' => 'value1' }} )
end
it { is_expected.to contain_cinder_config('ibm_svf/param1').with_value('value1') }
end
context 'ibm_svf backend with cinder type' do
before do
params.merge!( :manage_volume_type => true )
end
it { is_expected.to contain_cinder_type('ibm_svf').with(
:ensure => 'present',
:properties => ['volume_backend_name=ibm_svf']
)}
end
end
on_supported_os({
:supported_os => OSDefaults.get_supported_os
}).each do |os,facts|
context "on #{os}" do
let (:facts) do
facts.merge!(OSDefaults.get_facts())
end
it_behaves_like 'cinder::backend::ibm_svf'
end
end
end