94e4e8c5ae
The cinder-common package in Ubuntu and Debian used to provide the additional config file for tgt daemon to allow the daemon to expose volumes managed by cinder. However that config file is no longer provided by the package since Wallaby release and now creating attachment fails with the following warning in cinder-volume.log. ``` Failed to create iscsi target for Volume ID: volume-<UUID>. It could be caused by problem with concurrency. Also please ensure your tgtd config file contains 'include /var/lib/cinder/volumes/*' ``` This change ensures the include line is added in Ubuntu/Debian to fix the error. Closes-Bug: #1986518 Change-Id: I0c0615c919447164718c265af603fbc4f5e66b1e
143 lines
4.4 KiB
Puppet
143 lines
4.4 KiB
Puppet
#
|
|
# Define: cinder::backend::iscsi
|
|
#
|
|
# === Parameters:
|
|
#
|
|
# [*target_ip_address*]
|
|
# (optional) The IP address that the iSCSI daemon is listening on.
|
|
# Defaults to undef.
|
|
#
|
|
# [*volume_backend_name*]
|
|
# (optional) Allows for the volume_backend_name to be separate of $name.
|
|
# Defaults to: $name
|
|
#
|
|
# [*backend_availability_zone*]
|
|
# (Optional) Availability zone for this volume backend.
|
|
# If not set, the storage_availability_zone option value
|
|
# is used as the default for all backends.
|
|
# Defaults to $::os_service_default.
|
|
#
|
|
# [*volume_driver*]
|
|
# (Optional) Driver to use for volume creation
|
|
# Defaults to 'cinder.volume.drivers.lvm.LVMVolumeDriver'.
|
|
#
|
|
# [*volume_group*]
|
|
# (Optional) Name for the VG that will contain exported volumes
|
|
# Defaults to $::os_service_default
|
|
#
|
|
# [*volumes_dir*]
|
|
# (Optional) Volume configuration file storage directory
|
|
# Defaults to '/var/lib/cinder/volumes'.
|
|
#
|
|
# [*target_helper*]
|
|
# (Optional) iSCSI target user-land tool to use.
|
|
# Defaults to '$::cinder::params::target_helper'.
|
|
#
|
|
# [*target_protocol*]
|
|
# (Optional) Protocol to use as iSCSI driver
|
|
# Defaults to $::os_service_default.
|
|
#
|
|
# [*manage_volume_type*]
|
|
# (Optional) Whether or not manage Cinder Volume type.
|
|
# If set to true, a Cinder Volume type will be created
|
|
# with volume_backend_name=$volume_backend_name key/value.
|
|
# Defaults to false.
|
|
#
|
|
# [*extra_options*]
|
|
# (optional) Hash of extra options to pass to the backend stanza
|
|
# Defaults to: {}
|
|
# Example :
|
|
# { 'iscsi_backend/param1' => { 'value' => value1 } }
|
|
#
|
|
define cinder::backend::iscsi (
|
|
$target_ip_address = undef,
|
|
$volume_backend_name = $name,
|
|
$backend_availability_zone = $::os_service_default,
|
|
$volume_driver = 'cinder.volume.drivers.lvm.LVMVolumeDriver',
|
|
$volume_group = $::os_service_default,
|
|
$volumes_dir = '/var/lib/cinder/volumes',
|
|
$target_helper = $::cinder::params::target_helper,
|
|
$target_protocol = $::os_service_default,
|
|
$manage_volume_type = false,
|
|
$extra_options = {},
|
|
) {
|
|
|
|
include cinder::deps
|
|
include cinder::params
|
|
|
|
# NOTE(mnaser): Cinder requires /usr/sbin/thin_check to create volumes which
|
|
# does not get installed with Cinder (see LP#1615134).
|
|
if $::osfamily == 'Debian' {
|
|
if ! defined(Package['thin-provisioning-tools']) {
|
|
package { 'thin-provisioning-tools':
|
|
ensure => present,
|
|
tag => 'cinder-support-package',
|
|
}
|
|
}
|
|
}
|
|
|
|
cinder_config {
|
|
"${name}/volume_backend_name": value => $volume_backend_name;
|
|
"${name}/backend_availability_zone": value => $backend_availability_zone;
|
|
"${name}/volume_driver": value => $volume_driver;
|
|
"${name}/target_ip_address": value => $target_ip_address;
|
|
"${name}/target_helper": value => $target_helper;
|
|
"${name}/volume_group": value => $volume_group;
|
|
"${name}/volumes_dir": value => $volumes_dir;
|
|
"${name}/target_protocol": value => $target_protocol;
|
|
}
|
|
|
|
if $manage_volume_type {
|
|
cinder_type { $volume_backend_name:
|
|
ensure => present,
|
|
properties => ["volume_backend_name=${volume_backend_name}"],
|
|
}
|
|
}
|
|
|
|
create_resources('cinder_config', $extra_options)
|
|
|
|
case $target_helper {
|
|
'tgtadm': {
|
|
ensure_packages('tgt', {
|
|
'ensure' => present,
|
|
'name' => $::cinder::params::tgt_package_name,
|
|
'tag' => 'cinder-support-package',
|
|
})
|
|
|
|
ensure_resource('file_line', "cinder include ${volumes_dir}", {
|
|
'path' => '/etc/tgt/targets.conf',
|
|
'line' => "include ${volumes_dir}/*",
|
|
'match' => '#?include /',
|
|
'require' => Anchor['cinder::install::end'],
|
|
'notify' => Anchor['cinder::service::begin'],
|
|
})
|
|
|
|
ensure_resource('service', 'tgtd', {
|
|
'ensure' => running,
|
|
'name' => $::cinder::params::tgt_service_name,
|
|
'enable' => true,
|
|
'tag' => 'cinder-support-service',
|
|
})
|
|
}
|
|
|
|
'lioadm': {
|
|
ensure_resource('service', 'target', {
|
|
'ensure' => running,
|
|
'enable' => true,
|
|
'tag' => 'cinder-support-service',
|
|
})
|
|
|
|
ensure_packages('targetcli', {
|
|
'ensure' => present,
|
|
'name' => $::cinder::params::lio_package_name,
|
|
'tag' => 'cinder-support-package',
|
|
})
|
|
}
|
|
|
|
default: {
|
|
fail("Unsupported target helper: ${target_helper}.")
|
|
}
|
|
}
|
|
|
|
}
|